npt-japanese

% Macro WITH-SLOTS

Macro WITH-SLOTS

Macro WITH-SLOTS

構文

with-slots (slot-entry*) instance-form declaration* form* => result*
slot-entry ::= slot-name | (variable-name slot-name)

引数と戻り値

slot-name - スロット名、評価はされない
variable-name - 変数名、評価はされない
instance-form - フォーム、評価されてinstanceが生成される
instance - オブジェクト
declaration - 宣言式、評価はされない
form - フォーム、暗黙のprogn
result - フォームの返却値

定義

マクロwith-slotsは、slot-nameで指定されたinstanceのスロットを、変数のように参照するためのレキシカルな環境が作成されます。このような文脈では、スロットの値は、レキシカルに束縛された変数のように、そのスロット名を使用して使うことができます。スロットの値を設定するために setfとsetqの両方を使用することができます。

マクロwith-slotsは、スロット名が変数として現れるところを、 slot-valueの呼び出しに変換します。

例文

(defclass thing ()
          ((x :initarg :x :accessor thing-x)
           (y :initarg :y :accessor thing-y)))
=>  #<STANDARD-CLASS THING 250020173>
(defmethod (setf thing-x) :before (new-x (thing thing))
  (format t "~&Changing X from ~D to ~D in ~S.~%"
          (thing-x thing) new-x thing))
(setq thing (make-instance 'thing :x 0 :y 1)) =>  #<THING 62310540>
(with-slots (x y) thing (incf x) (incf y)) =>  2
(values (thing-x thing) (thing-y thing)) =>  1, 2
(setq thing1 (make-instance 'thing :x 1 :y 2)) =>  #<THING 43135676>
(setq thing2 (make-instance 'thing :x 7 :y 8)) =>  #<THING 43147374>
(with-slots ((x1 x) (y1 y))
            thing1
  (with-slots ((x2 x) (y2 y))
              thing2
    (list (list x1 (thing-x thing1) y1 (thing-y thing1)
                x2 (thing-x thing2) y2 (thing-y thing2))
          (setq x1 (+ y1 x2))
          (list x1 (thing-x thing1) y1 (thing-y thing1)
                x2 (thing-x thing2) y2 (thing-y thing2))
          (setf (thing-x thing2) (list x1))
          (list x1 (thing-x thing1) y1 (thing-y thing1)
                x2 (thing-x thing2) y2 (thing-y thing2)))))
>>  Changing X from 7 to (9) in #<THING 43147374>.
=>  ((1 1 2 2 7 7 8 8)
     9
     (9 9 2 2 7 7 8 8) 
     (9)
     (9 9 2 2 (9) (9) 8 8))

影響

defclass

例外

もしslot-nameがinstanceのスロット名ではない場合は、結果は定義されていません。

参考

with-accessors, slot-value, symbol-macrolet

備考

with-slotsの下記のフォームについて、

(with-slots (slot-entry1 ... slot-entryn) instance-form form1 ... formk)

これは、下記の展開と同等です。

(let ((in instance-form))
  (symbol-macrolet (Q1 ... Qn) form1 ... formk))

ただし、Qiは下記のようになります。

(slot-entryi () (slot-value in 'slot-entryi))

もしslot-entry_iがシンボルなら次のようになります。

(variable-namei () (slot-value in 'slot-namei))

もしslot-entry_iがフォームなら次のようになります。

(variable-namei 'slot-namei)

TOP, Github

This site is open source. Improve this page.